あいいー×びじゅあるべーしっくすくりぷと

見てくれてる人いるのかな？
お久しぶりです。どうも、僕ですc(・H・´ と⌒ｃ)つ彡


さて、今日はちょっとしたプログラム(スクリプト)のお話です。
私、NCV（コメントビューワー）使いながらIE8でニコニコ生放送見てるんですが、新しい放送が始まるたびに毎回NCVとIE8を起動するのがしんどくて。
しかも、他にIEを起動しちゃって、ウィンドウ位置がずれたりとかサイズ変更したまま保存して調整し直したり・・・と。
面倒だなぁ、と思っていたんです。

んで、あまりに面倒というかシステム的にもよろしくないので、初めてのVBでスクリプトを作ってみました。
VBを選んだのは、手軽でWindowsと親和性が高いからです。

環境は
・WindowsXP SP3
・InterNetExplorer8
です。
続きに仕様とスクリプトを書きます。長いので興味ない人はスルーで。

仕様は以下の通り

・スクリプト起動時にURLを引数として渡す
・起動時に、「IEを新規で開くか、既存を使用するか選択」できる
・IEを新規で開く場合、画面の左上に、特定の大きさで開く
・既存の(既に起動している)IEを使用する場合、現在のタブを上書きして放送ページを開く

以下、スクリプトを記述します。長いよ！ごめんね！

※私はVB始めてでかつ知識もBASICで止まった状態からなので、間違いなどあるかもしれません。
間違いあったら教えてもらえると助かります！

<スクリプト：ieopen.vbs>--------
Option Explicit
Const navOpenInNewTab = &H800
Const navOpenInBackgroundTab = &H1000

Dim objIE
Set objIE = Nothing 'Is Nothingでフラグチェックするため初期化
Dim objShell
Dim lngCount
Dim URL
Dim Answer

'引数をURLに格納
URL = WScript.Arguments(0)

'Shell.Applicationオブジェクトの作成
Set objShell = CreateObject("Shell.Application")

'動作選択
Answer = MsgBox ( "IEを新規に起動しますか？", vbYesNoCancel, "起動確認" )
Select Case Answer
  'はい(いまのところ処理無し)
  Case vbYes

  'いいえ(既に開いているIEを探す)
  Case vbNo
    For lngCount = 0 To ObjShell.Windows.Count - 1
      If Right(UCase(objShell.Windows(lngCount).FullName), 12) = "IEXPLORE.EXE" Then
        Set objIE = objShell.Windows(lngCount)
        Exit For '見つけたので、↑代入後、強制的にループを抜ける
      End If
    Next

    If objIE Is Nothing Then 'IEが見つけられなかったら終了する
      MsgBox "見つけられませんでした"
      WScript.Quit
    End If

  'キャンセル(処理終了)
  Case vbCancel
    MsgBox "キャンセルされました"
    WScript.Quit
End Select

'IEオブジェクトがないときは、新しく作成する
If objIE Is Nothing Then
  Set objIE = CreateObject("InternetExplorer.Application")
  'ウィンドウの大きさを変更
  objIE.Width = 612
  objIE.Height = 800

  '表示位置を変更
  objIE.Left = 0
  objIE.Top = 0

  'IE起動
  objIE.Navigate2 URL
  objIE.Visible = True

'IEオブジェクトがあるときは、タブを操作する（既存のタブを上書き）
Else
  objIE.Navigate2 URL '既存のタブ
End If

WScript.Quit

-----ここまで